ถ้าจะใช้งานผ่าน Blynk ผ่าน Siri

ถ้าผมต้องการเรียก ใช้ short cut ของ Siri ให้ สั่งทำงาน Blynk ผมได้ดูตัวอย่างแล้วติดครับ
สั่งงานผ่าน Siri อะไรก็ง่าย
ผมลองทำตามแล้วไม่ได้ เกิดจาก อะไรครับ เข้าใจ ว่า Server ตัวอย่างเป็น Blynk ถ้า ของผมจะเป็นของ oasiskit.com
ช่วยแนะนำด้วยครับ

#define BLYNK_PRINT Serial 
#include <ESP8266WiFi.h>
#include <BlynkSimpleEsp8266.h>
#define D0 13
#define D1 10

char auth[] = "wTmWsMa24qdqVUfK5Qpyg_1vzijJFS0Q"; //Token key
char server[] = "oasiskit.com";
char ssid[] = "Mi 10T Pro";
char pass[] = "12345678";
int port = 8080;
char led1 = D0;
char led2 = D1;

void setup() {
  Serial.begin(115200);
  Serial.println("กำลังเชื่อมต่อไปที่ Blynk Server");
  pinMode(D0, OUTPUT); //กำหนดโหมด ว่าเป็น INPUT หรือ OUTPUT
  pinMode(D1, OUTPUT);
  WiFi.begin(ssid, pass); //เชื่อมต่อ WiFi
  Blynk.config(auth, server, port); //กำหนด Token key , ชื่อ Server และ port
  Blynk.connect(); //เชื่อมต่อไปยัง Blynk
}

BLYNK_CONNECTED() {  // ฟังก์ชันนี้ทำงานเมื่อต่อ Blynk ได้ 
  Serial.println("App Blynk ทำงาน!");
}

void loop() {
  
  Blynk.run();

}

ขอดูลิ้ง API ที่เอาไปใช้หน่อยครับ

ขออภัยที่ตอบช้า :sweat_smile:
ทำได้แล้วครับ
Code

#define BLYNK_PRINT Serial
#include <ESP8266WiFi.h>
#include <BlynkSimpleEsp8266.h>

// token ,wifi user ,wifi password
char auth[] = "39QTbr-Eniy1JakpQesyeNOXCVGcke5Q"; //Token key
char server[] = "oasiskit.com";
char ssid[] = "Mi 10T Pro";
char pass[] = "12345678";
int port = 8080;

const int ledRed  = 4;
const int ledGre  = 0;
const int ledBlu  = 2;
const int button  = 5;
bool buttonStatus = 0;
bool buttonTemp = 0;

WidgetLED ledBlynk(V10);

BlynkTimer timer;

BLYNK_CONNECTED() {
 Serial.println("App Blynk ทำงาน!");
   Blynk.syncAll();
}

void checkStatusButton()
{
  buttonStatus = digitalRead(button);

  if (buttonStatus != buttonTemp)
  {
    if (buttonStatus == HIGH) {
      digitalWrite(ledRed, HIGH);
      Serial.println("LED Turned ON");
      Blynk.virtualWrite(V11, 1);
      ledBlynk.on();
    }
    else {
      digitalWrite(ledRed, LOW);
      Serial.println("LED Turned OFF");
      Blynk.virtualWrite(V11, 0);
      ledBlynk.off();
    }
    buttonTemp = buttonStatus;
  }
}

BLYNK_WRITE(V11)
{
  if (param.asInt() == 0)
  {
    digitalWrite(ledRed, LOW);
    ledBlynk.off();
  }
  if (param.asInt() == 1)
  {
    digitalWrite(ledRed, HIGH);
    ledBlynk.on();
  }
}

void setup() {
  Serial.begin(9600);
  //led
  pinMode(ledRed, OUTPUT);
  pinMode(ledGre, OUTPUT);
  pinMode(ledBlu, OUTPUT);
  //set default status
  digitalWrite(ledRed, LOW);
  digitalWrite(ledGre, LOW);
  digitalWrite(ledBlu, LOW);
  //button
  pinMode(button, INPUT);
  //start blynk
  WiFi.begin(ssid, pass); //เชื่อมต่อ WiFi
  Blynk.config(auth, server, port);
  Blynk.connect();
  timer.setInterval(500, checkStatusButton); 

}

void loop() {
  Blynk.run();
  timer.run();
}

URL active:
http://oasiskit.com:8080/39QTbr-Eniy1JakpQesyeNOXCVGcke5Q/update/V11?value=1
URL active:inactive :
http://oasiskit.com:8080/39QTbr-Eniy1JakpQesyeNOXCVGcke5Q/update/V11?value=0

ขอบคุณครับ

1 Like

เยี่ยมมากครับ ว่างๆ รีวิวให้ดูหน่อยนะครับ